82 Representations of Iwahori-Hecke algebras

Let W be a finite Coxeter group with generators {s_1, ldots, s_n}, and H = H(W, R, {q_i}) a corresponding Iwahori-Hecke algebra over the ring R as defined in chapter Iwahori-Hecke algebras. We shall now describe functions for dealing with representations and characters of H.

The fact that the algebra H is given by a presentation makes it particularly easy to work with representations. Assume we are given any set of matrices M_1,ldots,M_n in R^{d times d}. The fact that H is given by generators and defining relations immediately implies that there is a (unique) representation rho:H rightarrow R^{d times d} such that rho(T_{s_i})=M_i for all i, if and only if the matrices M_i satisfy the same relations as those for the generators T_{s_i} of H.

A general approach for the construction of representations is in terms of W-graphs, see cite[p.165]KL79. Any such W-graph carries a representation of H. Note that, for these purposes, it is necessary to assume that the parameters of H are squares of some elements of the ground ring. The simplest example, the standard W-graph defined in cite[Ex.~6.2]KL79 yields a ``deformation of the natural reflection representation of W. This can be produced in CHEVIE using the function HeckeReflectionRepresentation.

Another possibility to construct W-graphs is by using the Kazhdan-Lusztig theory of left cells (see KL79); see the following chapter for more details.

In a similar way as the ordinary character table of the finite Coxeter group W is defined, one also has a character table for the Iwahori-Hecke algebra H in the case when the ground ring A is a field such H is split and semisimple. The generic choice for such a ground ring is the rational function field K=overline{QQ}(v_1, ldots,v_n) where the parameters of the corresponding algebra H_K are given by q_i=v_i^2 for all~i.

By Tits' Deformation Theorem (see cite[Sec.~68]CR87, for example), the algebra H_K is (abstractly) isomorphic to the group algebra of W over K. Moreover, we have a bijection between the irreducible characters of H_K and W, given as follows. Let chi be an irreducible character of H_K. Then we have chi(T_w) in A where A=overline{ZZ}[v_1,ldots,v_n] and overline{ZZ} denotes the ring of algebraic integers in overline{QQ}. We can find a ring homomorphism f colon A rightarrow overline{QQ} such that f(a)=a for all a in overline{ZZ} and f(v_i)=1 for i=1,ldots,n. Then it turns out that the function chi_f colon w mapsto f(chi(T_w)) is an irreducible character of W, and the assignment chi mapsto chi_f defines a bijection between the irreducible characters of H_K and W.

Now this bijection does depend on the choice of f. But one should keep in mind that this only plays a role in the case where W is a non-crystallographic Coxeter group. In all other cases, as is well-known, the character table of W is rational; moreover, the values of the irreducible characters of H_K at basis elements T_w lie in the ring {ZZ}[v_1,ldots,v_n].

The character table of H_K is defined to be the square matrix (chi(T_w)) where chi runs over the irreducible characters of H_K and w runs over a set of representatives of em minimal length in the conjugacy classes of W. The character tables of Iwahori-Hecke algebras (in this sense) are known for all types: the table for type A was first computed by Starkey (see the description of his work in Car86); then different descriptions with different proofs were given in Ram91 and Pfe94b. The tables for the non crystallographic types I_2(m), H_3, H_4 can be constructed from the explicit matrix representations given in cite[Sec.~67C]CR87, Lus81 and AL82, respectively. For the classical types B and D see HR94 and Pfe96. The tables for the remaining exceptional types were computed in Gec94, Gec95 and GM97.

If H is an Iwahori-Hecke algebra over an arbitrary ground ring R as above, then the GAP function CharTable applied to the corresponding record returns a character table record which is build up in exactly the same way as for the finite Coxeter group W itself but where the record component irreducibles contains the character values which are obtained from those of the generic multi-parameter algebra H_K by specializing the indeterminates v_i to the variables in sqrtParameters.

Subsections

  1. HeckeReflectionRepresentation
  2. CheckHeckeDefiningRelations
  3. CharTable for Hecke algebras
  4. HeckeCharValues
  5. HeckeClassPolynomials
  6. PoincarePolynomial
  7. SchurElements
  8. SchurElement
  9. GenericDegrees
  10. HeckeCentralMonomials
  11. HeckeCharValuesGood

82.1 HeckeReflectionRepresentation

HeckeReflectionRepresentation( W )

returns a list of matrices which give the reflection representation of the Iwahori-Hecke algebra corresponding to the Coxeter group W. The function Hecke must have been applied to the record W.

    gap> v:= X( Rationals );;  v.name := "v";;
    gap> H := Hecke(CoxeterGroup( "B", 2) , v^2, v);
    Hecke(CoxeterGroup("B", 2),[ v^2, v^2 ],[ v, v ])
    gap> ref:= HeckeReflectionRepresentation( H );
    [ [ [ -v^0, 0*v^0 ], [ -v^2, v^2 ] ], 
      [ [ v^2, -2*v^0 ], [ 0*v^0, -v^0 ] ] ] 

    gap> H := Hecke( CoxeterGroup( "H", 3 ));;  
    gap> HeckeReflectionRepresentation( H );
    [ [ [ -1, 0, 0 ], [ -1, 1, 0 ], [ 0, 0, 1 ] ], 
      [ [ 1, E(5)+2*E(5)^2+2*E(5)^3+E(5)^4, 0 ], [ 0, -1, 0 ], 
          [ 0, -1, 1 ] ], [ [ 1, 0, 0 ], [ 0, 1, -1 ], [ 0, 0, -1 ] ] ]

This function requires the package "chevie" (see RequirePackage).

82.2 CheckHeckeDefiningRelations

CheckHeckeDefiningRelations( H , t ) returns true or false, according to whether a given set t of matrices corresponding to the standard generators of the Coxeter group Group(H) defines a representation of the Iwahori-Hecke algebra H or not.

    gap> H := Hecke(CoxeterGroup( "F", 4 ));;
    gap> r := HeckeReflectionRepresentation( H );;
    gap> CheckHeckeDefiningRelations( H, r );
    true 

This function requires the package "chevie" (see RequirePackage).

82.3 CharTable for Hecke algebras

CharTable( H )

CharTable returns the character table record of the Iwahori-Hecke algebra H. This is basically the same as the character table of a Coxeter group described earlier with the exception that the component irreducibles contains the matrix of the values of the irreducible characters of the generic Iwahori-Hecke algebra specialized at the parameters in the component parameter of H. Thus, if all these parameters are equal to~1 in QQ then the component irreducibles just contains the ordinary character table of the underlying Coxeter group.

The function CharTable first recognizes the type of H, then calls special functions for each type involved in H and finally forms the direct product of all these tables.

    gap> W := CoxeterGroup( "G", 2 );;
    gap> u := X( Rationals );;  u.name := "u";;
    gap> v := X( LaurentPolynomialRing( Rationals ) );; v.name := "v";;
    gap> u := u * v^0;;
    gap> H := Hecke( W, [ u^2, v^2 ], [ u, v ] );
    Hecke(CoxeterGroup("G", 2),[ u^2*v^0, v^2 ],[ u*v^0, v ])
    gap> Display( CharTable( H ) );
    H(G2)
    
                2   2             2       2          1         1          2
                3   1             .       .          1         1          1
   
                               ~A_1     A_1        G_2       A_2 A_1 + ~A_1
               2P                                  A_2       A_2           
               3P              ~A_1     A_1 A_1 + ~A_1           A_1 + ~A_1
  
    phi_{1,0}       1           v^2   (u^2)   (u^2)v^2  (u^4)v^4   (u^6)v^6
    phi_{1,6}       1            -1      -1          1         1          1
    phi_{1,3}'      1           v^2      -1       -v^2       v^4       -v^6
    phi_{1,3}''     1            -1   (u^2)     (-u^2)     (u^4)     (-u^6)
    phi_{2,1}     (2)      v^2+(-1) (u^2-1)       (u)v (-u^2)v^2 (-2u^3)v^3
    phi_{2,2}     (2)      v^2+(-1) (u^2-1)      (-u)v (-u^2)v^2  (2u^3)v^3

As mentioned before, the record components classparam, classnames and irredinfo contain canonical labels and parameters for the classes and Character tables for Coxeter groups and also ChevieCharInfo). For direct products, sequences of such canonical labels of the individual types are given.

We can also have character tables for algebras where the parameters are not necessarily indeterminates:

    gap> H1 := Hecke( W, [ E(6)^2, E(6)^4 ],[ E(6), E(6)^2 ] );
    Hecke(CoxeterGroup("G", 2),[ E(3), E(3)^2 ],[ -E(3)^2, E(3) ])
    gap> ct := CharTable( H1 );
    CharTable( "H(G2)" )
    gap> Display( ct );
    H(G2)
                 2 2    2   2          1   1          2
                 3 1    .   .          1   1          1
    
                     ~A_1 A_1        G_2 A_2 A_1 + ~A_1
                2P                   A_2 A_2
                3P   ~A_1 A_1 A_1 + ~A_1     A_1 + ~A_1
   
    phi_{1,0}      1    A  /A          1   1          1
    phi_{1,6}      1   -1  -1          1   1          1
    phi_{1,3}'     1    A  -1         -A  /A         -1
    phi_{1,3}''    1   -1  /A        -/A   A         -1
    phi_{2,1}      2    B  /B         -1  -1          2
    phi_{2,2}      2    B  /B          1  -1         -2
 
    A = E(3)^2
      = (-1-ER(-3))/2 = -1-b3
    B = E(3)+2*E(3)^2
      = (-3-ER(-3))/2 = -2-b3
    gap> RankMat( ct.irreducibles );
    5 

The last result tells us that the specialized character table is no more invertible.

Character tables of Iwahori--Hecke algebras were introduced in GP93; see also the introduction to this chapter for further information about the origin of the various tables.

This function requires the package "chevie" (see RequirePackage).

82.4 HeckeCharValues

HeckeCharValues( T [,irreds])

T is an element of an Iwahori-Hecke algebra (expressed in any basis) and irreds is a set of irreducible characters of the algebra (given as vectors). HeckeCharValues returns the values of irreds on the element T (the method used is to convert to the T basis, and then use HeckeClassPolynomials). If irreds is not given, all character values are returned.

    gap> q := X( Rationals );; q.name := "q";;
    gap> H := Hecke( CoxeterGroup( "B", 2 ), q ^ 2, q );;
    gap> HeckeCharValues( Basis( H, "C'" )( 1, 2, 1 ) );
    [ 0*q^0, q + q^(-1), 0*q^0, q^3 + 2*q + 2*q^(-1) + q^(-3), 
      -q - q^(-1) ] 

See also HeckeClassPolynomials.

This function requires the package "chevie" (see RequirePackage).

82.5 HeckeClassPolynomials

HeckeClassPolynomials( h [, reps] )

returns the class polynomials of the Hecke element h of the Hecke algebra H with respect to representatives reps of minimal length in the conjugacy classes of the Coxeter group Group(H).

If absent, reps is taken as CoxeterConjugacyClasses(Group(H)). These polynomials have the following property. Given the class polynomials p corresponding to h and the matrix X of the values of the irreducible characters of the Iwahori-Hecke algebra on T_w (for w in reps), then the product X*p is the list of values of the irreducible characters on the element h of the Iwahori-Hecke algebra.

    gap> u := X( Rationals );; u.name := "u";;
    gap> W := CoxeterGroup( "A", 3 );
    CoxeterGroup("A", 3)
    gap> H := Hecke( W, u );; 
    gap> h := Basis( H, "T" )( LongestCoxeterElement( W ) );
    T(1,2,1,3,2,1)
    gap> cp := HeckeClassPolynomials( h );
    [ 0*u^0, 0*u^0, u^2, u^3 - 2*u^2 + u, u^3 - u^2 + u - 1 ]
    gap> CharTable( H ).irreducibles * cp;
    [ u^0, -u^2, 2*u^3, -u^4, u^6 ] 

So, the entries in this list are the values of the irreducible characters on the basis element corresponding to the longest element in the Coxeter group.

The class polynomials were introduced in GP93.

This function requires the package "chevie" (see RequirePackage).

82.6 PoincarePolynomial

PoincarePolynomial( H )

The Poincaraccent19 e polynomial of the Hecke algebra H, which is equal to SchurElements(H)[ind] where ind is the position of the 1-dimensional index representation in the character table of H, that is, the representation which maps T_{s_i} to the corresponding parameter q_i.

    gap> q := X( Rationals );; q.name := "q";;
    gap> W := CoxeterGroup( "G", 2 );; H := Hecke( W, q );
    Hecke(CoxeterGroup("G", 2),[ q, q ],[  ])
    gap> PoincarePolynomial( H );
    q^6 + 2*q^5 + 2*q^4 + 2*q^3 + 2*q^2 + 2*q + 1 

This function requires the package "chevie" (see RequirePackage).

82.7 SchurElements

SchurElements( H )

returns the list of constants arising from the Schur relations for the irreducible characters of the Iwahori-Hecke algebra H.

The Schur element corresponding to an irreducible character chi is also equal to P/D_{chi} where P is the Poincare polynomial and D_{chi} is the generic degree of chi. Note, however, that this only works if D_{chi} neq 0. (We can have D_{chi}=0 if the parameters of H are suitably chosen roots of unity, for example.) The ordering of the degrees corresponds to the ordering of the characters as returned by the function CharTable. Note that the Schur element corresponding to the ind-character is the Poincare polynomial P.

    gap> u := X( Rationals );; u.name := "u";;
    gap> v := X( LaurentPolynomialRing( Rationals ) );; v.name := "v";;
    gap> schur := SchurElements( Hecke( CoxeterGroup( "G", 2 ), 
    >                                    [ u ^ 2, v ^ 2 ], [ u, v ] ) );
    [ (u^6 + u^4)*v^6 + (u^6 + 2*u^4 + u^2)*v^4 + (u^4 + 2*u^2 + 1)*v^
        2 + (u^2 + 1), (1 + u^(-2)) + (1 + 2*u^(-2) + u^(-4))*v^(
        -2) + (u^(-2) + 2*u^(-4) + u^(-6))*v^(-4) + (u^(-4) + u^(-6))*v^(
        -6), (u^(-4) + u^(-6))*v^6 + (u^(-2) + 2*u^(-4) + u^(-6))*v^4 + (
        1 + 2*u^(-2) + u^(-4))*v^2 + (1 + u^(-2)), 
      (u^2 + 1) + (u^4 + 2*u^2 + 1)*v^(-2) + (u^6 + 2*u^4 + u^2)*v^(
        -4) + (u^6 + u^4)*v^(-6), (2*u^0)*v^2 + (2*u - 2*u^(-1))*v + (2*u^
        2 - 2 + 2*u^(-2)) + (-2*u + 2*u^(-1))*v^(-1) + (2*u^0)*v^(-2), 
      (2*u^0)*v^2 + (-2*u + 2*u^(-1))*v + (2*u^2 - 2 + 2*u^(-2)) + (2*u - 
        2*u^(-1))*v^(-1) + (2*u^0)*v^(-2) ] 

The Poincaraccent19 e polynomial is just the Schur element corresponding to the trivial (or index) representation:

    gap> schur[1];
    (u^6 + u^4)*v^6 + (u^6 + 2*u^4 + u^2)*v^4 + (u^4 + 2*u^2 + 1)*v^
    2 + (u^2 + 1)

(But note that the trivial character is not always the first character!) For further information about generic degrees and connections with the representation theory of finite groups of Lie type, see BC72 and Car85.

This function requires the package "chevie" (see RequirePackage).

82.8 SchurElement

SchurElement( H, phi )

returns the constants arising from the Schur relations for the irreducible character phi of the Iwahori-Hecke algebra H. phi should be specified by its parameter (see CharParams in section Operations and functions for Coxeter groups) .

    gap> u := X( Rationals );; u.name := "u";;
    gap> v := X( LaurentPolynomialRing( Rationals ) );; v.name := "v";;
    gap> H := Hecke( CoxeterGroup( "G", 2 ), [ u ^ 2, v ^ 2 ], [ u, v ] );
    Hecke(CoxeterGroup("G", 2),[ u^2, v^2 ],[ u, v ])
    gap> SchurElement( H, [ [ 1, 3, "'" ] ] );
    (u^(-4) + u^(-6))*v^6 + (u^(-2) + 2*u^(-4) + u^(-6))*v^4 + (1 + 2*u^(
    -2) + u^(-4))*v^2 + (1 + u^(-2))

This function requires the package "chevie" (see RequirePackage).

82.9 GenericDegrees

We do not have a function for the generic degrees of an Iwahori-Hecke algebra since they are not always defined (for example, if the parameters of the algebra are roots of unity). If we have a generic multi-parameter Iwahori-Hecke algebra H then the generic degrees are certainly defined, and they can be computed with the command:

List( SchurElements( H ), x - PoincarePolynomial( H ) / x );

(See PoincarePolynomial and SchurElement.)

82.10 HeckeCentralMonomials

HeckeCentralMonomials( HW )

Returns the scalars by which the central element T_{w_0}^2 acts on irreducible representations of HW.

    gap> v := X( Cyclotomics );; v.name := "v";;
    gap> H := Hecke( CoxeterGroup( "H", 3 ), v ^ 2, v );;
    gap> HeckeCentralMonomials( H );
    [ v^0, v^60, v^24, v^36, v^20, v^20, v^40, v^40, v^30, v^30 ]

This function requires the package "chevie" (see RequirePackage).

82.11 HeckeCharValuesGood

HeckeCharValuesGood( HW, w )

Let HW be a Hecke algebra for the Coxeter group CoxeterGroup(HW), let w be a good element of CoxeterGroup(HW) in the sense of GM97, and let d be the order of w.

HeckeCharValuesGood computes the values of the irreducible characters of the Iwahori-Hecke algebra HW on T_w^d. The point is that the character table of the Hecke algebra is not used, and that all the eigenvalues of T_w^d are monomials in HW.parameters, so this can be used to find the absolute value of the eigenvalues of T_w, a step towards computing the character table of the Hecke algebra.

We continue the example in HeckeCentralMonomial:

    gap> HeckeCharValuesGood( H, [ 1, 2, 3 ] );
    [ v^0, v^60, 5*v^24, 5*v^36, 3*v^20, 3*v^20, 3*v^40, 3*v^40, 4*v^30, 
      4*v^30 ]

This function requires the package "chevie" (see RequirePackage). Previous Up Next
Index

GAP 3.4.4
April 1997